apply plugin: 'java-library'
apply plugin: 'eclipse'
apply plugin: 'maven'
apply plugin: 'signing'

repositories {
	maven { url 'http://maven.aliyun.com/nexus/content/groups/public/' }
}

dependencies {
	compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.26'
	compile group: 'xyz.noark', name: 'noark-log', version: '3.3.3.Final'
}

group = 'xyz.noark'
version = '1.0.0.Final'
	
sourceCompatibility = 1.8  
targetCompatibility = 1.8  

[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

jar {
    manifest.attributes provider: '小流氓'
	manifest.attributes["Created-By"] = "${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})"
	manifest.attributes["Implementation-Title"] = project.name
	manifest.attributes["Implementation-Version"] = project.version
}
    
javadoc {
    options{
    	encoding "UTF-8"
    	charSet 'UTF-8'
    	author true
    	version true
    	links "http://docs.oracle.com/javase/8/docs/api/"
    }
}
    
ext."signing.keyId"='15567893'
ext."signing.password"=System.getenv('SIGNING_PASSWORD')
ext."signing.secretKeyRingFile"=System.getenv('SIGNING_SECRETKEYRINGFILE')
	
signing {
	sign configurations.archives
}
	
uploadArchives {
	repositories {
	    mavenDeployer {
	        beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
	
	        repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
	            authentication(userName: System.getenv('OSSRH_USER'), password: System.getenv('OSSRH_PASSWORD'))
	        }
	
		    //快照版本还是内网速度快，稳定再发布正式版本给大家使用
	        snapshotRepository(url: "http://192.168.51.231:8081/repository/maven-snapshots/") {
	            authentication(userName: 'admin', password: 'admin123')
	        }
	            
	        pom.project {
	        	name 'noark-slf4j-impl'
	        	packaging 'jar'
	        	description 'This is a noark slf4j impl.'
	        	url 'http://noark.xyz'
	
	        	scm {
	          		connection 'scm:git@gitee.com:xiaoe/noark-slf4j-impl.git'
	          		developerConnection 'scm:git@gitee.com:xiaoe/noark-slf4j-impl.git'
	          		url 'https://gitee.com/xiaoe/noark-slf4j-impl'
	        	}
	
	        	licenses {
	          		license {
	            		name 'The Apache License, Version 2.0'
	            		url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
	          		}
	        	}
	
	        	developers {
	          		developer {
	            		id 'xiaoe'
		            	name '小流氓'
		            	email '176543888@qq.com'
		            	url "http://blog.noark.xyz"
	          		}
	        	}
	        }
	    }
	}
}
	
task sourceJar(type: Jar) {
	from sourceSets.main.allJava
	classifier = 'sources'
}
	
task javadocJar(type: Jar) {
	from javadoc
    classifier = 'javadoc'
}
	
artifacts {
    archives sourceJar
    archives javadocJar
}