ext {
    println("Environment          : JAVA_HOME=$System.env.JAVA_HOME")
    println("Gradle Version       : ${projectProperties.getProperty('gradleVersion')}")
    println("Target JDK Version   : ${projectProperties.getProperty('javaVersion')}")
    println("Kotlin Version       : $versions.kotlin")
    println("Spring Boot Version  : $versions.springBoot")
    println("Acp Version          : $versions.acp")
    println("Encoding             : ${projectProperties.getProperty('encoding')}")
}

buildscript {
    ext {
        projectProperties = new Properties()
        projectProperties.load(new FileInputStream("$rootDir${File.separator}project.properties"))
    }
    apply from: "$rootDir${File.separator}gradle${File.separator}dependencies.gradle"
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$versions.kotlin"
        classpath "org.jetbrains.kotlin:kotlin-allopen:$versions.kotlin"
        classpath "org.jetbrains.kotlin:kotlin-noarg:$versions.kotlin"
        classpath "org.springframework.boot:spring-boot-gradle-plugin:$versions.springBoot"
    }
    repositories {
        mavenLocal()
        maven {
            url = new URI(projectProperties.getProperty('mavenCentralUrl').toString())
        }
        maven {
            url = new URI(projectProperties.getProperty('mavenCentralAliyunUrl').toString())
        }
        mavenCentral()
    }
}

apply from: "$rootDir${File.separator}gradle${File.separator}globalTask.gradle"
apply from: "$rootDir${File.separator}gradle${File.separator}moduleVersion.gradle"

allprojects {

    group project.group.toString().isBlank() ? projectProperties.getProperty('group') : "${projectProperties.getProperty('group')}.$project.group"

    apply from: "$rootDir${File.separator}gradle${File.separator}dependencies.gradle"

    apply plugin: 'java'
    apply plugin: 'kotlin'
    apply plugin: 'kotlin-kapt'
    apply plugin: 'kotlin-spring'
    apply plugin: 'kotlin-noarg'
    apply plugin: 'kotlin-jpa'
    apply plugin: 'idea'

    apply from: "$rootDir${File.separator}gradle${File.separator}environment.gradle"
    apply from: "$rootDir${File.separator}gradle${File.separator}commonTask.gradle"

    buildscript {
        repositories {
            mavenLocal()
            maven {
                url = new URI(projectProperties.getProperty('mavenCentralUrl').toString())
            }
            maven {
                url = new URI(projectProperties.getProperty('mavenCentralAliyunUrl').toString())
            }
            mavenCentral()
        }
    }

    repositories {
        mavenLocal()
        maven {
            url = new URI(projectProperties.getProperty('mavenCentralUrl').toString())
        }
        maven {
            url = new URI(projectProperties.getProperty('mavenCentralAliyunUrl').toString())
        }
        mavenCentral()
    }

    dependencies {
        testImplementation("org.junit.jupiter:junit-jupiter:$versions.jupiter")
        testImplementation("org.junit.platform:junit-platform-launcher:$versions.junitPlatform")
        implementation "org.jetbrains.kotlin:kotlin-stdlib"
        implementation "org.jetbrains.kotlin:kotlin-reflect"
        implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$versions.kotlinCoroutines"
    }

    java {
        sourceCompatibility = projectProperties.getProperty('javaVersion')
        targetCompatibility = projectProperties.getProperty('javaVersion')
        withJavadocJar()
        withSourcesJar()
    }

    javadoc {
        options.charSet = projectProperties.getProperty('encoding')
        options.encoding = projectProperties.getProperty('encoding')
        options.addStringOption('Xdoclint:none', '-quiet')
    }

    kapt {
        useBuildCache = true
        includeCompileClasspath = false
    }

    compileJava {
        options.encoding = projectProperties.getProperty('encoding')
    }
    compileJava.dependsOn(processResources)
    compileTestJava {
        options.encoding = projectProperties.getProperty('encoding')
    }

    compileKotlin.dependsOn(processResources)

    test {
        useJUnitPlatform()
        testLogging {
            events "standardOut", "started", "passed", "skipped", "failed"
        }
        exclude "**${File.separator}*nobuild**"
    }
}